!***********************************************************************************
!**                                                                               **
!**      Auteur: Ambroise BROU                                                    ** 
!**      Cree en Aout 2005                                                        **
!**      Derniere mis a jour Decemnbre 2006                                       **
!**                                                                               **
!***********************************************************************************

/TITLE, Treillis pour grue
/UNITS,SI			! unites en systeme international
/PREP7  			! entree en mode pre-traitement
!*  
ET,1,LINK8		  	! element fini de type LINK8  

E=210E9				! module d'Young du materiau
SIGMA=0.27			! coefficient de Poisson du materiau 
RHO=7800			! masse volumique du materiau
A1=2.2E-3			! section 1
A2=1.1E-3			! section 2
R,1,A1				! constantes reelles du matriau 1: A1=2.2E-3 m2
R,2,A2				! constantes reelles du matriau 1: A2=1.1E-3 m2
MP,EX,1,E			
MP,PRXY,1,SIGMA 		
MP,DENS,1,RHO
G=9.81				! intensite de la pesanteur
M=5000				! charge
F=M*G				! module de la force appliquee a l'extremite du treillis

! Geometrie du Pylone: numero et coordonnees des noeuds 
N,1,0,0,1   
N,2,2,0,1
N,3,4,0,1  
N,4,6,0,1
N,5,8,0,0   
N,6,6,0,-1
N,7,4,0,-1
N,8,2,0,-1
N,9,0,0,-1
N,10,1,3**0.5,0
N,11,3,3**0.5,0
N,12,5,3**0.5,0
N,13,6,3**0.5,0

SAVE				! sauvegarde de la base de donnees

! Creation des elements constitutifs du pylone 

REAL,1				! constante reelle 1 pour les elements qui suivent

EN,1,1,2
EN,2,2,3
EN,3,3,4
EN,4,4,5
EN,5,5,6
EN,6,6,7
EN,7,7,8
EN,8,8,9
EN,9,10,11
EN,10,11,12
EN,11,12,13

REAL,2				! constante reelle 2 pour le reste des elements
EN,12,9,1
EN,13,9,2
EN,14,2,8
EN,15,2,7
EN,16,7,3
EN,17,7,4
EN,18,4,6
EN,19,1,10
EN,20,10,2
EN,21,2,11
EN,22,11,3
EN,23,3,12
EN,24,12,4
EN,25,4,13
EN,26,13,5
EN,27,6,13
EN,28,6,12
EN,29,12,7
EN,30,7,11
EN,31,11,8
EN,32,8,10
EN,33,10,9

! Conditions aux limites en deplacement
D,1,ALL,0
D,9,ALL,0
D,10,ALL,0

! Force appliquee au treillis
F,5,FY,-F			! application de la force F suivant y sur le noeud 5
ACEL,0,G,0			! acceleration suivant la direction y

FINISH				! fin du mode pre-traitement
/SOLU				! mode solution
ANTYPE, STATIC			! analyse statique
SOLVE				! demarrage de la resolution
SAVE				! sauvegarde de la base de donnees
/POST1				! entree en mode post-traitement
SET,1,LAST
/VIEW,1,1,1,1
/PBC,ALL,,1
!/PBC,F,,1			! afficage des forces 
PLNSOL,U,SUM,1,1,0		! affichage solution nodale pour le deplacement