!****************************************************
!**                                                **
!**      Auteur: Ambroise BROU                     ** 
!**      Cree en Aout 2005                         **
!**      Mis a jour en Octobre 2006                **
!**                                                **
!****************************************************
/TITLE, Poutre sur deux appuis soumise a une charge repartie variable 
/UNITS,SI							! systeme international d'unite
/PREP7  							! entree en mode preprocessing
!*
L=5								! longueur de la poutre en m
Q1=10000							! charge repartie en N/m
Q2=37000							! charge repartie en N/m
LE=0.25								! longueur de chaque element
 
ET,1,BEAM3							! type d'element fini: BEAM3
KEYOPT,1,6,1							! affichage des forces et des moments
KEYOPT,1,9,9							! affichage de 9 points intermediaires entre les noeuds I et J
!*  
R,1,43.00E-4,549.70E-8,0.14 					! constantes reelles du materiau 1: aire, moment d'inertie et hauteur
								! A=43.00E-4 m2, Izz=549.70E-8 m4, H=0.14 m 
MP,EX,1,210E9							! module d'elasticite du materiau 1 en Pa
MP,PRXY,1,0.3							! coefficient de poisson du materiau 1

! Numero et coordonnees des points cles
K,1,0,0
K,2,L,0
L,1,2								! creation de la droite reliant les points 1 et 2
LESIZE,ALL,LE							! division de la ligne en n elements de longueur LE m
LMESH,1								! maillage de la ligne representant la poutre
/PNUM,ELEM,1							! affichage du numero de chaque element
EPLOT 								! affichage des elements
SAVE								! sauvegarde de la base de donnees
D,1,UX,0							! deplacement au noeud 1 nul suivant x
D,1,UY,0							! deplacement au noeud 1 nul suivant y
D,2,UY,0							! deplacement au noeud 2 nul suivant y
!Application des 2 charges uniformement reparties
ESEL,S,,,1,4							! selection des elements 1 a 4
SFBEAM,ALL,1,PRES,Q1						! application de la charge Q1 sur les elements preselectionnes
ESEL,S,,,17,20							! selection des elements 17 a 20
SFBEAM,ALL,1,PRES,Q2						! application de la charge Q2 sur les elements preselectionnes
ALLS
! Definition de l'equation de la charge								! reselection de toutes les entites
*DEL,_FNCNAME   
*DEL,_FNCMTID   
*DEL,_FNCCSYS   
*SET,_FNCNAME,'charge'  
*SET,_FNCCSYS,0 
! /INPUT,..\Dossier_ANSYS\charge_cubique.func,,,1   
*DIM,%_FNCNAME%,TABLE,6,15,1,,,,%_FNCCSYS%  
!   
! Begin of equation: 21000-24000*{X}+15000*{X}^2-2000*{X}^3 
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0 
*SET,%_FNCNAME%(3,0,1), 0.0 
*SET,%_FNCNAME%(4,0,1), 0.0 
*SET,%_FNCNAME%(5,0,1), 0.0 
*SET,%_FNCNAME%(6,0,1), 0.0 
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 24000, 0, 0, 2  
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 1, -1, 3, 2 
*SET,%_FNCNAME%(0,3,1),   0, -1, 0, 21000, 0, 0, -2 
*SET,%_FNCNAME%(0,4,1), 0.0, -3, 0, 1, -1, 2, -2
*SET,%_FNCNAME%(0,5,1), 0.0, -1, 0, 2, 0, 0, 2  
*SET,%_FNCNAME%(0,6,1), 0.0, -2, 0, 1, 2, 17, -1
*SET,%_FNCNAME%(0,7,1), 0.0, -1, 0, 15000, 0, 0, -2 
*SET,%_FNCNAME%(0,8,1), 0.0, -4, 0, 1, -1, 3, -2
*SET,%_FNCNAME%(0,9,1), 0.0, -1, 0, 1, -3, 1, -4
*SET,%_FNCNAME%(0,10,1), 0.0, -2, 0, 3, 0, 0, 2 
*SET,%_FNCNAME%(0,11,1), 0.0, -3, 0, 1, 2, 17, -2   
*SET,%_FNCNAME%(0,12,1), 0.0, -2, 0, 2000, 0, 0, -3 
*SET,%_FNCNAME%(0,13,1), 0.0, -4, 0, 1, -2, 3, -3   
*SET,%_FNCNAME%(0,14,1), 0.0, -2, 0, 1, -1, 2, -4   
*SET,%_FNCNAME%(0,15,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: 21000-24000*{X}+15000*{X}^2-2000*{X}^3   
!-->
ESEL,S,,,5,16,1  						! selection des elements 5 a 16
SFBEAM,ALL,1,PRES,%charge%,%charge% 				! application de la charge variable sur chaque element selectionne
ALLS								! reselection de toutes les entites
SAVE								! sauvegarde de la base de donnees
FINISH								! fin du mode preprocessing
/SOLU								! entree en mode solution
ANTYPE,STATIC							! analyse statique							
SOLVE								! demarrage de la resolution
FINISH								! sortie du mode solution
/POST1								! mode post-traitement
SET,1,LAST							! lecture du dernier set de resultat
ETABLE,IMFZ,SMISC,6						! ecriture dans un tableau de la valeur du moment flechissant au noeud I de chaque element
ETABLE,JMFZ,SMISC,66						! ecriture dans un tableau de la valeur du moment flechissant au noeud J de chaque element					
ETABLE,IFZ,SMISC,2						! ecriture dans un tableau de la valeur de l'effort tranchant au noeud I de chaque element
ETABLE,JFZ,SMISC,62						! ecriture dans un tableau de la valeur de l'effort tranchant au noeud J de chaque element
/PSF,PRES,NORM,1,0,1						! affichage de la charge repartie
/PLOPTS,DATE,0
/WINDOW,1,TOP							! disposition de la fenetre 1 au en haut
/RATIO,1,1,2
PLLS,IFZ,JFZ							! affichage des elements du tableau de l'effort tranchant
/WINDOW,1,OFF							! deselection de la fenetre 1
/NOERASE							! eviter l'effacement de la fenetre entre deux affichages
/WINDOW,2,BOT							! disposition de la fenetre 2 en dessous
/RATIO,2,1,2
PLLS,IMFZ,JMFZ							! affichage des elements du tableau du moment flechissant
SAVE